Il modello gratuito: cosa c’è dentro
Scarica il modello di gestione magazzino in Excel (formato .xlsx, si apre anche con Google Fogli e LibreOffice). Niente macro. I fogli sono tre:
- Istruzioni: come si usa in cinque punti, più i limiti del file scritti chiari.
- Articoli: l’anagrafica, colonne da A a H: Codice, Descrizione, Ubicazione, Scorta minima (le scrivi tu), Caricato, Scaricato, Giacenza, Stato (si calcolano da sole). Le formule sono già pronte per 200 articoli, dalla riga 2 alla 201, e restano vuote finché la colonna Codice è vuota.
- Movimenti: il registro, colonne da A a F: Data, Codice, Tipo, Quantità, Documento, Note. Codice e Tipo si scelgono da un menu a tendina, la quantità deve essere un numero maggiore di zero. Le convalide coprono le righe da 2 a 2000.
In tutti e due i fogli la riga d’intestazione resta bloccata quando scorri. Quando la giacenza di un articolo scende alla scorta minima o sotto, tutta la riga in Articoli si colora.
Il file contiene quattro articoli e sette movimenti di esempio, da cancellare prima di iniziare. Danno questo risultato:
| Articolo | Scorta minima | Caricato | Scaricato | Giacenza | Stato |
|---|---|---|---|---|---|
| ART-001 Scatola cartone | 50 | 200 | 165 | 35 | Da riordinare |
| ART-002 Nastro adesivo | 20 | 60 | 25 | 35 | OK |
| ART-003 Etichette | 10 | 30 | 0 | 30 | OK |
| ART-004 Pallet EPAL | 5 | 12 | 8 | 4 | Da riordinare |
Perché due fogli e non uno
L’errore più comune è un unico foglio con una colonna “quantità” che si aggiorna a mano: arriva la merce, si cancella 40 e si scrive 90. Funziona per una settimana. Poi una cifra sbagliata non si può più ricostruire, perché non resta traccia di cosa è successo.
Con un registro dei movimenti ogni carico e ogni scarico resta scritto, con data e documento. La giacenza diventa un risultato, non un dato da mantenere: se non torna, puoi risalire al movimento sbagliato.

Come si usa, passo per passo
Aggiungere un articolo. In Articoli scrivi codice, descrizione, ubicazione e scorta minima nella prima riga libera. Le altre quattro colonne si riempiono da sole e il nuovo codice compare subito nel menu a tendina del registro.
Registrare un carico. Arriva la merce con il DDT del fornitore. In Movimenti, nella prima riga libera: data di arrivo, codice dal menu, tipo Carico, quantità, numero del DDT in Documento.
Registrare uno scarico. Esce merce per un ordine, per la produzione o per un reso a fornitore: stessa cosa con tipo Scarico e il riferimento all’ordine. La quantità si scrive sempre positiva, è il tipo a dire se entra o esce.
Controllare cosa riordinare. In Articoli filtra la colonna Stato su “Da riordinare” (Dati → Filtro): è la lista per gli acquisti.
E si registra subito, non a fine giornata.
Per vedere costruire da zero un foglio di carico e scarico c’è la lezione di Daniele Castelletti (Associazione Maggiolina), in italiano: è del 2018, ma le funzioni sono le stesse.
Le formule, spiegate
Nel foglio Articoli, per l’articolo nella riga 2 (nel file sono già copiate fino alla riga 201):
| Colonna | Formula | Cosa fa |
|---|---|---|
| E · Caricato | =SOMMA.PIÙ.SE(Movimenti!$D:$D; Movimenti!$B:$B; $A2; Movimenti!$C:$C; "Carico") |
Somma le quantità dei movimenti di quell’articolo di tipo Carico |
| F · Scaricato | =SOMMA.PIÙ.SE(Movimenti!$D:$D; Movimenti!$B:$B; $A2; Movimenti!$C:$C; "Scarico") |
Lo stesso, per gli scarichi |
| G · Giacenza | =E2-F2 |
Caricato meno scaricato |
| H · Stato | =SE(G2<=D2; "Da riordinare"; "OK") |
Avvisa quando scendi alla scorta minima |
Nel file ogni formula è racchiusa in =SE($A2=""; ""; …): se la riga non ha un codice, la cella resta vuota invece di mostrare zeri. Nella versione inglese di Excel le funzioni si chiamano SUMIFS e IF e il separatore è la virgola: il file si adatta da solo alla lingua del tuo Excel.
I controlli già inclusi evitano gli errori più frequenti:
- Convalida dei dati su Codice e Tipo del registro (Dati → Convalida dati → Elenco): chi registra un movimento sceglie da un menu, quindi niente "carico " con uno spazio o codici inesistenti.
- Quantità maggiore di zero: un numero negativo o una parola vengono rifiutati.
- Formattazione condizionale con la regola
=$H2="Da riordinare"sulle righe da A a H: la lista della spesa salta all’occhio.
Due aggiunte utili, se vuoi rinforzare il file:
| Controllo | Dove | Formula |
|---|---|---|
| Codici duplicati vietati | Articoli, colonna A: Convalida dati → Personalizzato | =CONTA.SE($A$2:$A$201; A2)=1 |
| Giacenza negativa in rosso | Articoli, colonna G: Formattazione condizionale | =$G2<0 |
Una giacenza negativa vuol dire sempre un errore di registrazione: uno scarico sul codice sbagliato o un carico dimenticato. Infine, con Revisione → Proteggi foglio puoi bloccare le colonne calcolate, così nessuno scrive una giacenza a mano sopra una formula.
Codici articolo e ubicazioni fatti bene
Le formule confrontano il testo del codice: basta uno spazio o uno zero in meno e l’articolo diventa un altro. Per questo il codice è la cosa da progettare meglio.
- Univoco e stabile: mai riutilizzato per un prodotto diverso, e senza fornitore o prezzo dentro, che cambiano.
- Stesso formato per tutti: ART-001, mai art-1 o ART 001, che per Excel sono articoli diversi.
- Una sola unità di misura, scritta nella descrizione: caricare a scatole e scaricare a pezzi falsa la giacenza.
L’ubicazione dice dove trovare la merce. Nel modello è nel formato corsia-scaffale-ripiano: A-01-2 vuol dire corsia A, scaffale 01, ripiano 2. Con la stessa etichetta sullo scaffale, chiunque trova la merce. Se lo stesso articolo sta in due posti, Excel comincia a fare fatica: serve la giacenza per ubicazione, e lì si entra nel territorio di un WMS.
Come calcolare la scorta minima
La scorta minima del modello è la soglia di riordino: la quantità sotto la quale devi ordinare per non restare senza merce mentre aspetti il fornitore. Una formula semplice e sufficiente per la maggior parte delle PMI:
scorta minima = consumo medio giornaliero × giorni di consegna del fornitore + scorta di sicurezza
Esempio ipotetico: consumi 12 scatole al giorno, il fornitore consegna in 5 giorni lavorativi e vuoi un margine di 2 giorni. Scorta minima = 12 × 5 + 12 × 2 = 60 + 24 = 84 scatole.
Il consumo medio lo ricavi dal registro. Per gli scarichi degli ultimi 30 giorni:
=SOMMA.PIÙ.SE(Movimenti!D:D; Movimenti!B:B; A2; Movimenti!C:C; "Scarico"; Movimenti!A:A; ">="&OGGI()-30)/21
Si divide per 21, i giorni lavorativi in circa 30 giorni di calendario, perché anche la consegna è in giorni lavorativi. Ricalcola la scorta minima ogni due o tre mesi e prima dei picchi: cambiano vendite e fornitori. Il tempo di consegna è un lead time: misuralo sui DDT reali, non su quello promesso.
Quanto vale il magazzino: costo medio e FIFO
A fine anno serve sapere quanto vale la merce, e lungo l’anno quanti soldi sono fermi sugli scaffali. Per i beni fungibili il codice civile (art. 2426, comma 1, n. 10) ammette tre metodi: costo medio ponderato, FIFO (primo entrato, primo uscito) e LIFO (ultimo entrato, primo uscito). Il metodo per il bilancio si concorda con il commercialista; per la gestione quotidiana basta essere coerenti.
Esempio ipotetico, sull’articolo ART-001 del modello, con prezzi d’acquisto inventati:
| Movimento | Quantità | Costo unitario | Valore |
|---|---|---|---|
| Carico del 3/11 | 200 | 0,80 € | 160,00 € |
| Scarico del 10/11 | 165 | — | — |
| Carico del 24/11 | 150 | 0,90 € | 135,00 € |
| Giacenza | 185 |
- Costo medio ponderato del periodo: valore dei carichi ÷ quantità caricata = 295,00 € ÷ 350 = 0,8429 € a pezzo. Valore della giacenza: 185 × 0,8429 € = 155,93 €.
- FIFO: sono usciti per primi i pezzi più vecchi, quindi restano 35 pezzi a 0,80 € e 150 a 0,90 €: 28,00 € + 135,00 € = 163,00 €.
Con i prezzi in salita il FIFO dà un valore più alto, perché a scaffale restano i pezzi pagati di più: qui 7,07 € in più.
In Excel il costo medio è il più semplice da tenere. Aggiungi in Movimenti una colonna G Costo unitario, compilata sui carichi, e in Articoli due colonne:
| Colonna | Formula |
|---|---|
| I · Costo medio | =MATR.SOMMA.PRODOTTO((Movimenti!$B$2:$B$2000=A2)*(Movimenti!$C$2:$C$2000="Carico")*Movimenti!$D$2:$D$2000*Movimenti!$G$2:$G$2000)/E2 |
| J · Valore | =G2*I2 |
La somma della colonna J è il valore del magazzino. Se il registro parte da un inventario iniziale, caricalo come primo movimento con il suo costo, e scrivi il costo anche sulle rettifiche in carico: senza, abbassano la media. Il FIFO in Excel si può fare, ma richiede di seguire ogni lotto d’acquisto fino a esaurimento: è il punto in cui un foglio diventa un progetto.
Rotazione e giorni di copertura
Due indicatori dicono se le scorte sono troppe o troppo poche, e si calcolano dal registro.
Indice di rotazione = quantità scaricata nel periodo ÷ giacenza media del periodo
Esempio ipotetico: le scatole ART-001 escono a 12 al giorno per 250 giorni lavorativi, cioè 3.000 l’anno. La giacenza era 220 a inizio anno e 280 a fine anno, quindi la giacenza media è (220 + 280) ÷ 2 = 250. Rotazione = 3.000 ÷ 250 = 12 volte l’anno: in media una scatola resta a scaffale 365 ÷ 12 = circa 30 giorni.
Giorni di copertura = giacenza attuale ÷ consumo medio giornaliero
Con 180 scatole a scaffale e 12 al giorno, la copertura è 180 ÷ 12 = 15 giorni lavorativi. Sotto i giorni di consegna del fornitore sei già in ritardo; molto sopra, stai immobilizzando denaro.
In contabilità la rotazione si calcola a valore (costo del venduto ÷ valore medio delle rimanenze); per decidere cosa ordinare serve quella a quantità. Gli articoli che non ruotano sono i candidati a svendita o reso. Sono KPI da guardare ogni mese.
Inventario: far tornare i conti
Almeno una volta all’anno si conta la merce fisicamente. Se il conteggio non coincide con la giacenza calcolata, non si corregge la formula: si registra un movimento di rettifica con documento “Inventario” e la data del conteggio. Nel modello la quantità deve essere positiva, quindi una differenza in meno è uno Scarico e una in più è un Carico. Così il registro resta la storia completa del magazzino, errori compresi.
Invece di fermare tutto un giorno all’anno, molte aziende fanno l’inventario a rotazione con la classificazione ABC: si ordinano gli articoli per valore consumato in un anno (quantità scaricata × costo medio) e si dividono in tre classi.
Esempio ipotetico, un magazzino di 400 articoli:
| Classe | Articoli | Quota del valore consumato | Quante volte si contano | Conteggi in un anno |
|---|---|---|---|---|
| A | 60 | circa 80% | ogni mese | 720 |
| B | 100 | circa 15% | ogni trimestre | 400 |
| C | 240 | circa 5% | una volta l’anno | 240 |
| Totale | 400 | 1.360 |
Sono 1.360 conteggi l’anno, poco più di 110 al mese, e gli articoli che pesano di più si controllano dodici volte invece di una. In Excel: copia Codice e valore consumato in un foglio a parte, ordina per valore decrescente, calcola la quota cumulata con =SOMMA($B$2:B2)/SOMMA($B$2:$B$401) e assegna la classe con =SE(C2<=0,8; "A"; SE(C2<=0,95; "B"; "C")).
Lotti e scadenze in Excel: fin dove arriva
Alimentari, cosmetici, farmaceutico, componenti con certificato: qui la giacenza per articolo non basta, serve quella per lotto. In Excel si fa aggiungendo al registro le colonne H · Lotto e I · Scadenza (la G è il costo unitario visto sopra), e su ogni movimento il lotto va scritto, scarichi compresi. La giacenza di un lotto è la solita SOMMA.PIÙ.SE con un criterio in più (Movimenti!H:H; "L-2611"). Per vederli tutti insieme è più comoda una tabella pivot: aggiungi una colonna “Quantità con segno” con =SE(C2="Scarico"; -D2; D2) e metti Codice e Lotto nelle righe e quella colonna nei valori.
Funziona, ma con tre limiti seri. Nessuno impedisce di scaricare il lotto sbagliato, perché il foglio non sa quale scade prima (il criterio FEFO, first expired first out). Un richiamo da un cliente richiede di filtrare a mano chi ha ricevuto quel lotto. E con decine di lotti per articolo le formule rallentano e gli errori di battitura si moltiplicano. Se lotti e scadenze sono la norma e non l’eccezione, è il primo segnale che il foglio è arrivato al limite.
Excel, Google Fogli o un software
| Excel sul computer | Excel su OneDrive o Google Fogli | Software di magazzino | |
|---|---|---|---|
| Costo | Licenza che hai già | Incluso in Microsoft 365 o gratis con Google | Abbonamento o progetto |
| Più persone insieme | No, il file si blocca o si duplica | Sì, in contemporanea | Sì, con permessi per ruolo |
| Chi ha fatto cosa | No | Cronologia delle versioni e delle modifiche, non un registro per movimento | Storico di ogni movimento con utente e ora |
| Da smartphone in magazzino | No | Sì, ma digitando | App con lettura dei codici a barre |
| Lotti, scadenze, ubicazioni | Colonne e formule a mano | Colonne e formule a mano | Gestiti, con blocchi sugli errori |
| Collegamento a ordini ed e-commerce | Copia e incolla | Copia e incolla | Automatico |
Un dettaglio pratico: un lettore di codici a barre USB funziona anche con Excel, perché “scrive” il codice nella cella come una tastiera. È un buon modo per ridurre gli errori di battitura prima di cambiare strumento.
Sei segnali che Excel non basta più

Excel è un ottimo punto di partenza. Smette di esserlo quando:
- Più persone lo modificano insieme e nessuno sa qual è l’ultima versione.
- La giacenza non torna e non capisci dove nasce la differenza.
- Servono lotti, scadenze o più ubicazioni.
- Gli ordini si scrivono due volte: nel gestionale, nell’e-commerce e nel foglio.
- In magazzino serve lo smartphone con il lettore di codici a barre.
- Devi sapere chi ha fatto cosa e quando, per un cliente, un audit o una certificazione.
Dopo Excel: software pronto o su misura
Le strade sono due:
- Un gestionale o un software di magazzino pronto, in abbonamento. Conviene quando il tuo modo di lavorare è standard: carico da DDT, scarico da ordine, inventario. Si parte in pochi giorni e si spende poco.
- Un software di gestione magazzino su misura, quando il processo ha regole tue: lotti e varianti particolari, conto lavoro con terzisti, collegamento con produzione, e-commerce o macchine. Ne parliamo nel dettaglio, con fasce di prezzo, nella guida ai costi di un gestionale su misura.
Spesso la soluzione giusta è una via di mezzo: tenere il gestionale che già avete e aggiungere un’app di magazzino da smartphone che legge i codici a barre e scrive i movimenti al posto vostro.
Il modello come specifica
C’è un vantaggio di partire da Excel che pochi considerano: un foglio usato per qualche mese è la migliore specifica che puoi dare a chi ti svilupperà il software. Colonne, codici, tipi di movimento ed eccezioni che hai dovuto gestire dicono esattamente cosa serve, meglio di qualsiasi riunione. Se vuoi capire se è il momento di passare a un software, mandaci il tuo file: lo guardiamo e ti diciamo cosa conviene, anche se la risposta è “tieni Excel ancora un anno”.



